home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Extra Heft 12
/
Extra Heft12.bin
/
input64
/
06_85.d64
/
haushaltsbelege
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-08-16
|
17KB
|
575 lines
100 IFPEEK(50307)=120THENPOKE50257,0
1000 REM*HAUSHALTSBELEGE*GERHARD MUELLER-GREIF*0561/44440*010485
1010 REM ************************MENUE**************************
1020 POKE53280,1:POKE53281,1
1030 RESTORE:PRINTCHR$(142);CHR$(8);"[154][147]";
1040 PRINT"[176][192][192][192][195][192][192][192][192][192][192][192][192][192][192][192][192][192][174][146] "
1050 PRINT"[194] HAUSHALTSBELEGE [194][146] "
1060 PRINT"[173][192][192][192][192][195][192][192][192][192][192][192][192][192][192][192][192][192][189][146] "
1070 PRINT
1080 PRINT"[176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174][146]";
1090 PRINT"[194][146] F1 [146] EINGABE DER BELEGE [194][146]";
1100 PRINT"[171][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][179][146]";
1110 PRINT"[194][146] F3 [146] AUSGABE NACH KRITERIEN [194][146]";
1120 PRINT"[171][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][179][146]";
1130 PRINT"[194][146] F5 [146] KORREKTUR NACH BELEG-NR. [194][146]";
1140 PRINT"[171][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][179][146]";
1150 PRINT"[194][146] F7 [146] ABSPEICHERN / VERIFIZIEREN [194][146]";
1164 PRINT"[173][192][192][195][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][195][195][195][192][192][192][192][192][192][192][192][189][146]";
1170 PRINT"":FR=FRE(64):R=INT(FR/38)
1180 PRINT" [213][195][195][195][195][195][195][195][201]"
1190 PRINT" [194] [194] _ BYTES FREI"
1200 PRINT" [202][195][195][195][195][195][195][195][203]";"[145][157][157][157][157][157][157][157][157]";FR
1210 PRINT" NOCH ";""R"[157] EINGABEN [146]";" MOEGLICH ! "
1220 READDZ:DZ=DZ+1:BN=DZ-10000:BL=BN-1
1230 IFBL<10THENBL$=""+STR$(BL)+"[157][157][157]00"
1240 IFBL>9ANDBL<100THENBL$=STR$(BL)+"[157][157][157]0"
1250 IFBL>99THENBL$="[157]"+STR$(BL)
1260 IFR=2THENPRINT" VORLETZTE DATENEINGABE [146]"
1270 IFR=1THENPRINT" LETZTE DATENEINGABE [146]"
1280 IFR<1THENPRINT" ENDE DER DATENEINGABE [146]"
1290 GETMW$:IFMW$="[133]"ANDR>1THEN1350
1300 IFMW$="[134]"THEN2240
1310 IFMW$="[135]"THEN4520
1320 IFMW$="[136]"THEN5070
1330 GOTO1290
1340 REM ******************** E I N G A B E *********************
1350 IFBN<10THENBN$=""+STR$(BN)+"[157][157][157]00"
1360 IFBN>9ANDBN<100THENBN$=STR$(BN)+"[157][157][157]0"
1370 IFBN>99THENBN$="[157]"+STR$(BN)
1380 PRINT"[147]DATUM :TT.MM.JJ "
1390 PRINT"[145]BELEG-NR.:"BN$"[146]"
1400 PRINT"BETRAG :******* "
1410 PRINT"BER./ART.:[187][187][187][187][187]......."
1420 PRINT"EINN./AUSG.(+/-):*"
1430 IFPF$="N"THEN1470
1440 IFK<>1THENPRINT"****************************************[146]"
1450 IFK=1THENPRINTCHR$(18);" ";D2$;" ";D3$;" ";D4$;" ";D5$
1460 GOTO1490
1470 PRINTCHR$(18);" ";LEFT$(B$,8);" ";MID$(B$,9,7);
1480 PRINT" ";MID$(B$,16,12);" ";RIGHT$(B$,1);" "
1490 PRINT"<CR>[146] ZEILENSPRUNG - LOESCHEN[146]......"
1500 PRINT"<DEL>[146] KORREKTUR IN DER ZEILE"
1510 PRINT"<C=><M>[146] ABBRUCH DER EINGABE, MENUE"
1520 PRINT" [187][187][187][187][187] B E L E G B E R E I C H E [187][187][187][187][187] [146]"
1530 PRINT" AUTO- BANK- BEKL- BERUF "
1540 PRINT" COMP- LEBEN SCHEC SONST "
1550 PRINT" TABAK VERS- WOHN- ZEIT-"
1560 CS$=""
1570 EL=8:B$="":N$="TT.MM.JJ"
1580 GETEZ$:IFEZ$=CHR$(167)THENRUN
1590 IFE$=""ANDEZ$=CHR$(13)THEN1820
1600 IFEZ$=CHR$(13)THEN1940
1610 IFEZ$=CHR$(44)THENEZ$=CHR$(46)
1620 IFEZ$=CHR$(20)ANDLEN(E$)<1THEN1580
1630 IFEZ$=CHR$(20)THENE$=LEFT$(E$,LEN(E$)-1):GOTO1690
1640 IFEZ$>CHR$(15)ANDEZ$<CHR$(32)THEN1580
1650 IFEZ$>CHR$(95)THEN1580
1660 E$=E$+EZ$
1670 IFEL=7OREL=8THENIFLEN(E$)=ELTHEN1940
1680 IFLEN(E$)=ELTHEN1830
1690 L=LEN(E$)
1700 PRINTCS$;E$;MID$(N$,L+1,EL-L);" "
1710 PRINTCS$;"";:FORI=0TOL:PRINT" ";:NEXT:PRINT"[157]^ "
1720 GOTO1580
1730 PRINT"":PRINTCS$+E$+" "
1740 IFEL=8THENEL=7:N$="*******":GOTO1790
1750 IFEL=7THENEL=12:N$="[187][187][187][187][187].......":GOTO1790
1760 IFEL=12THENEL=1:N$="*":GOTO1790
1770 IFEL=1ANDK=1THENB$=B$+E$:DZ=BN+10000
1780 IFEL=1THENB$=B$+E$:GOTO5660
1790 B$=B$+E$:E$="":CS$=CS$+""
1800 IFEL=1THENCS$=CS$+""
1810 GOTO1690
1820 E$=LEFT$("............",EL)
1830 PRINT"":PRINTCS$;E$;" OK?<CR>[146]"
1840 IFEL=8THENPRINT"[145] "
1850 IFEL<>8THENPRINT" "
1860 SI=54272:POKESI+7,109:POKESI+8,175:POKESI+11,33
1870 POKESI+12,0:POKESI+13,240:POKESI+24,15
1880 GETEF$:POKESI+11,0
1890 IFEF$=CHR$(167)THENRUN
1900 IFEF$=CHR$(13)THEN1730
1910 IFEF$=CHR$(20)THEN1930
1920 GOTO1880
1930 E$=LEFT$(E$,LEN(E$)-1):GOTO1690
1940 IFEL<>7ANDEL<>8THENNL$="............"
1950 IFEL<>7ANDEL<>8THENE$=LEFT$(E$+NL$,EL):GOTO1690
1960 ZL=LEN(E$):FORI=1TOZL
1970 IFMID$(E$,I,1)="."ANDMID$(E$,I+1,1)="."THEN1990
1980 NEXT:GOTO2000
1990 E$=LEFT$(E$,I):GOTO1690
2000 FORI=1TOZL:MI$=MID$(E$,I,1)
2010 IFMI$<CHR$(48)ANDMI$<>CHR$(46)THEN2040
2020 IFMI$>CHR$(57)THEN2040
2030 NEXT:GOTO2050
2040 E$=LEFT$(E$,I-1):GOTO1690
2050 IFEL=8THEN2170
2060 VK=0:FORI=1TOZL:IFMID$(E$,I,1)="."THEN2080
2070 VK=VK+1:NEXT
2080 NK=ZL-VK-1:IFNK>2THENE$=LEFT$(E$,VK+1):GOTO1690
2090 VN$="0000.00"
2100 IFVK<=4THENVL=4-VK:NL=7-ZL-VL
2110 IFVK<=4THENE$=LEFT$(VN$,VL)+E$+RIGHT$(VN$,NL)
2120 IFVK=5ANDZL=5THENE$=E$+".0"
2130 IFVK=5ANDZL=6THENE$=E$+"0"
2140 IFVK=6ANDZL=6THENE$=E$+"."
2150 IFVK<=4ANDRIGHT$(E$,1)="."THENE$=LEFT$(E$,VK+1):GOTO1690
2160 GOTO1830
2170 IFLEN(E$)<8THEN1690
2180 IFLEFT$(E$,1)="."THENE$="":GOTO1690
2190 IFMID$(E$,3,1)<>"."THENE$="":GOTO1690
2200 IFMID$(E$,6,1)<>"."THENE$=LEFT$(E$,3):GOTO1690
2210 IFRIGHT$(E$,1)="."THENE$=LEFT$(E$,7):GOTO1690
2220 GOTO1830
2230 REM ************ A U S G A B E K R I T E R I E N ***********
2240 PRINT"[147] AUSGABEKRITERIUM ? [146]"
2250 PRINT" 1 [146] EINN./AUSG."
2260 PRINT" 2 [146] MONAT.JAHR"
2270 PRINT" 3 [146] JAHR"
2280 PRINT" 4 [146] TAGESDATUM"
2290 PRINT" 5 [146] BETRAG"
2300 PRINT" 6 [146] BER./ARTIKEL"
2310 PRINT" 7 [146] BELEG-NR."
2320 PRINT" <C=><M>[146] MENUE"
2330 GETKW$:IFKW$=CHR$(167)THENRUN
2340 IFVAL(KW$)<1ORVAL(KW$)>7THEN2330
2350 IFKW$="6"THENK$="BER./ARTIKEL":N$="[187][187][187][187][187].......":GOTO2430
2360 IFKW$="7"THENKL=3:K$="BELEG-NR.":N$="...":GOTO2920
2370 IFKW$="5"THENKL=7:K$="BETRAG":N$="*******"
2380 IFKW$="4"THENKL=8:K$="TAGESDATUM":N$="TT.MM.JJ"
2390 IFKW$="3"THENKL=2:K$="JAHR":N$="JJ"
2400 IFKW$="2"THENKL=5:K$="MONAT.JAHR":N$="MM.JJ"
2410 IFKW$="1"THENKL=1:K$="EINN./AUSG.":N$="*"
2420 GOTO2520
2430 PRINTCHR$(18);"[147] AUSGABEKRITERIUM ";K$;" ":PRINT:PRINT
2440 PRINT" L [146] AUSWAHL V. LI. WAEHLBAR"
2450 PRINT" F [146] AUSWAHL NACH 5 STELLEN"
2460 PRINT" Z [146] AUSWAHL NACH 12 STELLEN"
2470 PRINT" <C=><M>[146] MENUE"
2480 GETZF$:IFZF$=CHR$(167)THENRUN
2490 IFZF$="Z"ORZF$="L"THENKL=12:GOTO2520
2500 IFZF$="F"THENKL=5:N$="[187][187][187][187][187]":GOTO2520
2510 GOTO2480
2520 PRINTCHR$(18);"[147] AUSGABEKRITERIUM ";K$;" ";ZF$;" "
2530 CS$="":IFKL=3THENCS$=CS$+""
2540 PRINTCS$;N$:IFKW$<>"7"THENPRINT"":GOTO2600
2550 PRINT"[145][145][145]BELEG-NR."
2560 PRINT" LETZTE BELEG-NR.: [146]";
2570 IFBL<10THENPRINTCHR$(18);BL$;" "
2580 IFBL>9ANDBL<100THENPRINTCHR$(18);BL$;" "
2590 IFBL>99THENPRINTCHR$(18);"[157] ";BL$;" "
2600 PRINT"<CR>[146] WEITER "
2610 PRINT"<DEL>[146] KORREKTUR "
2620 PRINT"<C=><M>[146] MENUE"
2630 GETAZ$:IFAZ$=CHR$(167)THENRUN
2640 IFFW$="F"ANDAZ$=CHR$(13)THEN3040
2641 IFFW$="F"ANDAZ$=CHR$(20)THEN2690
2642 IFFW$="F"AND(AZ$<CHR$(48)ORAZ$>CHR$(90))THEN2770
2643 IFFW$="F"AND(AZ$>CHR$(57)ANDAZ$<CHR$(65))THEN2770
2650 IFZF$="L"ANDAZ$=CHR$(13)THEN3040
2660 IFV$=""ANDAZ$=CHR$(13)THEN3050
2670 IFAZ$=CHR$(13)THEN3140
2680 IFAZ$=CHR$(44)THENAZ$=CHR$(46)
2690 IFAZ$=CHR$(20)ANDLEN(V$)<1THEN2630
2700 IFAZ$=CHR$(20)THENV$=LEFT$(V$,LEN(V$)-1):GOTO2770
2710 IFAZ$>CHR$(15)ANDAZ$<CHR$(32)THEN2630
2720 IFEZ$>CHR$(95)THEN2630
2730 V$=V$+AZ$
2740 IFKL=3ANDV$="000"THENV$="00"
2750 IFKW$="1"ORKW$="6"ORFW$="F"THENIFLEN(V$)=KLTHEN3060
2760 IFLEN(V$)=KLTHEN3160
2770 L=LEN(V$)
2780 PRINTCS$;V$;MID$(N$,L+1,KL-L);" "
2790 PRINTCS$;"";:FORI=0TOL:PRINT" ";:NEXT:PRINT"[157]^ "
2800 GOTO2630
2810 PRINTCS$+V$+NN$+" ":PRINT
2820 IFBW$="A"THENPRINT""
2830 PRINT" B [146] BILDSCHIRMAUSGABE "
2840 PRINT" P [146] PLOTTER- / DRUCKER- "
2850 PRINT" & BILDSCHIRMAUSGABE"
2860 PRINT"<C=><M>[146] MENUE "
2870 IFBW$="A"THENPRINT"[145][145][145][145][145][145][145][145][145][145][145][145] "
2880 GETAW$:IFAW$=CHR$(167)THENRUN
2890 IFAW$="P"THEN5910
2900 IFAW$="B"THEN3660
2910 GOTO2880
2920 PRINT"[147] AUSGABEKRITERIUM ";K$
2930 PRINT" E [146] EINZELBELEG"
2940 PRINT" B [146] BELEGFOLGE"
2950 PRINT" A [146] ALLE BELEGE"
2960 PRINT"<C=><M>[146] MENUE"
2970 GETBW$:IFBW$=CHR$(167)THENRUN
2980 IFBW$="E"THEN2520
2990 IFBW$="B"THEN3520
3000 IFBW$="A"THEN3020
3010 GOTO2970
3020 K$="ALLE BELEGE"
3030 PRINT"";CHR$(18);" AUSGABEKRITERIUM ";K$;" ":GOTO2810
3040 IFV$=""THEN2630
3045 NN$=" ":GOTO3060
3050 V$=LEFT$("............",KL)
3060 PRINT"":PRINTCS$;V$;LEFT$(NN$,KL-LEN(V$));" OK?<CR>[146]"
3070 PRINT" "
3080 GETAF$:IFAF$=CHR$(167)THENRUN
3090 IFAF$=CHR$(20)THEN3130
3100 IFFW$="F"ANDAF$=CHR$(13)THENFI$=V$:GOTO5210
3110 IFAF$=CHR$(13)THEN2810
3120 GOTO3080
3130 V$=LEFT$(V$,LEN(V$)-1):GOTO2630
3140 IFKW$="1"ORKW$="6"THENNL$="............"
3150 IFKW$="1"ORKW$="6"THENV$=LEFT$(V$+NL$,KL):GOTO2770
3160 ZL=LEN(V$):FORI=1TOZL
3170 IFMID$(V$,I,1)="."ANDMID$(V$,I+1,1)="."THEN3190
3180 NEXT:GOTO3200
3190 V$=LEFT$(V$,I):GOTO2770
3200 FORI=1TOZL:MI$=MID$(V$,I,1)
3210 IFMI$="."ANDKL=3THEN3250
3220 IFMI$<CHR$(48)ANDMI$<>"."THEN3250
3230 IFMI$>CHR$(57)THEN3250
3240 NEXT:GOTO3260
3250 V$=LEFT$(V$,I-1):GOTO2770
3260 IFKL=8THEN3410
3270 IFKL=5THEN3420
3280 IFKL=2THEN3430
3290 IFKL=3THEN3470
3300 VK=0:FORI=1TOZL:IFMID$(V$,I,1)="."THEN3320
3310 VK=VK+1:NEXT
3320 NK=ZL-VK-1:IFNK>2THENV$=LEFT$(V$,VK+1):GOTO2770
3330 VN$="0000.00"
3340 IFVK<=4THENVL=4-VK:NL=7-ZL-VL
3350 IFVK<=4THENV$=LEFT$(VN$,VL)+V$+RIGHT$(VN$,NL)
3360 IFVK=5ANDZL=5THENV$=V$+".0"
3370 IFVK=5ANDZL=6THENV$=V$+"0"
3380 IFVK=6ANDZL=6THENV$=V$+"."
3390 IFVK<=4ANDRIGHT$(V$,1)="."THENV$="":GOTO2770
3400 GOTO3060
3410 IFMID$(V$,6,1)<>"."THENV$=LEFT$(V$,3):GOTO2770
3420 IFMID$(V$,3,1)<>"."THENV$="":GOTO2770
3430 IFLEFT$(V$,1)="."THENV$="":GOTO2770
3440 IFRIGHT$(V$,1)="."THENV$=LEFT$(V$,KL-1):GOTO2770
3450 IFLEN(V$)<KLTHEN2770
3460 GOTO3060
3470 VN$="000"
3480 V$=LEFT$(VN$,3-ZL)+V$
3490 IFV$="000"THENV$="00":GOTO2770
3500 IFVAL(V$)>BLTHENV$="":GOTO2770
3510 GOTO3060
3520 CS$="":K$="BELEGFOLGE"
3530 PRINT"";CHR$(18);" AUSGABEKRITERIUM ";K$;" "
3540 PRINT" VON BELEG-NR.:":GOTO4560
3550 BA$=SN$:SN$=""
3560 IFVAL(BA$)>BLTHENBA$="":GOTO4730
3570 PRINT"";CHR$(18);" AUSGABEKRITERIUM ";K$;" ";BA$;" - "
3580 PRINT" BIS[146] BELEG-NR.:":GOTO4560
3590 BE$=SN$:SN$=""
3600 IFVAL(BE$)<VAL(BA$)THENBE$="":GOTO4730
3610 V$=BA$+" - "+BE$
3620 PRINT"";CHR$(18);" AUSGABEKRITERIUM ";K$;" ";V$;" "
3630 GOTO2810
3640 REM **** A U S G A B E D R U C K E R / M O N I T O R ****
3650 OPEN10,GA,0
3660 IFZF$<>"Z"ANDZF$<>"L"THEN3720
3670 PRINTCHR$(18);"[147] AUSGABEKRITERIUM ";K$;" "
3680 PRINTCHR$(18);" ";V$;" "
3690 IFAW$="P"THENPRINT#10," AUSGABEKRITERIUM ";K$
3700 IFAW$="P"THENPRINT#10," ";V$
3710 GOTO3740
3720 PRINTCHR$(18);"[147] AUSGABEKRITERIUM ";K$;" ";V$;" "
3730 IFAW$="P"THENPRINT#10," AUSGABEKRITERIUM ";K$;" ";V$
3740 IFBW$<>"B"THENPRINT
3750 IFAW$="P"THENPRINT#10,""
3760 PRINT"BEL. DATUM BETRAG BER./ARTIKEL *":PRINT
3770 IFAW$="P"THENPRINT#10,"BEL. DATUM BETRAG ";
3780 IFAW$="P"THENPRINT#10,"BER./ARTIKEL *":PRINT#10,""
3790 FORI=1TO17
3800 READD$:IFD$="ENDE"THEN4080
3810 IFLEFT$(D$,2)="10"ANDMID$(D$,6,2)=""THEN3800
3820 IFI=1ANDBA$=LEFT$(D$,3)THEN3950
3830 IFI>1ANDBW$="B"THEN3950
3840 IFBW$="A"THEN3950
3850 IFKW$="1"ANDV$=MID$(D$,31,1)THEN3950
3860 IFKW$="2"ANDV$=MID$(D$,7,5)THEN3950
3870 IFKW$="3"ANDV$=MID$(D$,10,2)THEN3950
3880 IFKW$="4"ANDV$=MID$(D$,4,8)THEN3950
3890 IFKW$="5"ANDV$=MID$(D$,12,7)THEN3950
3900 IFKL=12ANDV$=MID$(D$,19,12)THEN3950
3910 IFKL=5ANDV$=MID$(D$,19,5)THEN3950
3920 IFZF$="L"ANDV$=MID$(D$,19,LEN(V$))THEN3950
3930 IFKW$="7"ANDV$=LEFT$(D$,3)THEN3950
3940 GOTO3800
3950 D1$=LEFT$(D$,3)+" "
3960 D2$=MID$(D$,4,8)+" "
3970 D3$=MID$(D$,12,7)+" "
3980 D4$=MID$(D$,19,12)+" "
3990 D5$=MID$(D$,31,1)+" "
4000 IFK=1THENRETURN
4010 PRINTD1$;D2$;D3$;D4$;D5$;
4020 IFAW$="P"THENPRINT#10,D1$;D2$;D3$;D4$;D5$
4030 IFD5$="- "THENS=S-VAL(D3$):SA=SA+VAL(D3$)
4040 IFD5$="+ "THENS=S+VAL(D3$):SE=SE+VAL(D3$)
4050 IFBE$=LEFT$(D$,3)THEN4080
4060 IFI=17THEN4380
4070 NEXT
4080 IFAW$="P"THENPRINT#10,""
4090 PRINT
4100 PRINT"KEIN (WEITERER) BELEG"
4110 PRINT
4120 IFAW$="P"THENPRINT#10,"KEIN (WEITERER) BELEG"
4130 IFAW$="P"THENPRINT#10,""
4140 S=INT(S*100+.5)/100:Z$=STR$(ABS(S))
4150 IFS>0THENPRINTCHR$(18);" HABEN: ";
4160 GOSUB4440:IFS>0THENPRINTSPC(8-VK)Z$;" "
4170 IFAW$="P"ANDS>0THENPRINT#10," HABEN DM: ";SPC(8-VK)Z$
4180 IFS<0THENPRINTCHR$(18);" SOLL : ";SPC(8-VK)Z$;" "
4190 IFAW$="P"ANDS<0THENPRINT#10," SOLL DM: ";SPC(8-VK)Z$
4200 IFS=0THENPRINTCHR$(18);" EINN. / AUSG. AUSGEGLICHEN "
4210 IFAW$="P"ANDS=0THENPRINT#10," EINN. / AUSG. AUSGEGLICHEN "
4220 PRINT:Z$=""
4230 IFAW$="P"THENPRINT#10,""
4240 SA=INT(SA*100+.5)/100:Z$=STR$(SA):GOSUB4440
4250 PRINT" AUSG.: ";SPC(8-VK)Z$;" ";
4260 IFAW$="P"THENPRINT#10," AUSG. DM: ";SPC(8-VK)Z$
4270 Z$="":IFAW$="P"THENPRINT#10,""
4280 SE=INT(SE*100+.5)/100:Z$=STR$(SE):GOSUB4440
4290 PRINT" EINN.: ";SPC(8-VK)Z$
4300 IFAW$="P"THENPRINT#10," EINN. DM: ";SPC(8-VK)Z$
4310 Z$="":IFAW$="P"THENFORI=1TO6:PRINT#10,"":NEXT
4320 CLOSE10
4330 PRINT" P [146] AUSDRUCKEN";
4340 PRINT" <C=><M>[146] MENUE"
4350 GETAW$:IFAW$=CHR$(167)THENRUN
4360 IFAW$="P"THENRESTORE:S=0:SA=0:SE=0:GOTO5910
4370 GOTO4350
4380 PRINT" ^ [146] WEITER";
4390 PRINT" <C=><M>[146] MENUE"
4400 PRINT
4410 GETFF$:IFFF$=CHR$(167)THENRUN
4420 IFFF$="^"THENI=2:GOTO3800
4430 GOTO4410
4440 ZL=LEN(Z$):VK=0:NK=0
4450 FORI=1TOZL:IFMID$(Z$,I,1)="."THEN4470
4460 VK=VK+1:NEXT
4470 IFVK<ZLTHENNK=ZL-VK-1
4480 IFVK=ZLTHENNK=0:Z$=Z$+".00"
4490 IFNK=1THENZ$=Z$+"0"
4500 RETURN
4510 REM ****************** K O R R E K T U R *******************
4520 K=1:N$="..."
4530 CS$=""
4540 PRINTCHR$(18);"[147] WELCHER BELEG SOLL KORRIGIERT WERDEN? "
4550 PRINT" BELEG-NR."
4560 RESTORE:L=0:PRINTCS$;N$;" "
4570 PRINT" ";CHR$(18);" LETZTE BELEG-NR.: ";
4580 IFBL<10THENPRINTCHR$(18);BL$;" ";
4590 IFBL>9ANDBL<100THENPRINTCHR$(18);BL$;" ";
4600 IFBL>99THENPRINTCHR$(18);BL$;" ";
4610 PRINTCHR$(146);" "
4620 PRINT" <CR>[146] WEITER "
4630 PRINT" <DEL>[146] KORREKTUR "
4640 PRINT" <C=><M>[146] MENUE "
4650 GETSZ$:IFSZ$=CHR$(167)THENRUN
4660 IFSZ$=CHR$(20)ANDLEN(SN$)<1THEN4650
4670 IFSZ$=CHR$(20)THENSN$=LEFT$(SN$,LEN(SN$)-1):GOTO4730
4680 IFSZ$=CHR$(13)THEN4920
4690 IFSZ$<CHR$(48)ORSZ$>CHR$(57)THEN4740
4700 SN$=SN$+SZ$
4710 IFSN$="000"THENSN$="00"
4720 IFLEN(SN$)=3THEN4960
4730 L=LEN(SN$)
4740 PRINTCS$;SN$;MID$(N$,L+1,3-L);" "
4750 PRINTCS$;"";:FORI=0TOL:PRINT" ";:NEXT:PRINT"[157]^ "
4760 GOTO4650
4770 READD$
4780 IFLEFT$(D$,2)="10"ANDMID$(D$,6,2)=""THEN4770
4790 IFSN$=LEFT$(D$,3)THEN4830
4800 IFD$="ENDE"THENPRINT" BELEG NICHT VORHANDEN [146]"
4810 IFD$="ENDE"THENPRINT:PRINT:GOTO4860
4820 GOTO4770
4830 GOSUB3950
4840 PRINTCHR$(18)" ";D1$;D2$;D3$;D4$;"[157]";D5$
4850 PRINT" N [146] NEUEINGABE"
4860 PRINT" W [146] WEITERSUCHEN "
4870 IFD$="ENDE"THENPRINT"[145][145][145][145] "
4880 GETKF$:IFKF$=CHR$(167)THENRUN
4890 IFKF$="N"THENBN=VAL(D1$):GOTO1350
4900 IFKF$="W"THENSN$="":GOTO4560
4910 GOTO4880
4920 IFLEN(SN$)=2THENSN$="0"+SN$
4930 IFLEN(SN$)=1THENSN$="00"+SN$
4940 IFLEN(SN$)<1THEN4650
4950 IFSN$="000"THENSN$="00":GOTO4730
4960 IFVAL(SN$)>BLTHENSN$="":GOTO4730
4970 PRINT"";CS$;SN$;" OK?<CR>[146]"
4980 PRINT" "
4990 GETSF$:IFSF$=CHR$(167)THENRUN
5000 IFSF$=CHR$(20)THEN5060
5010 IFSF$=CHR$(13)ANDK=1THEN5050
5020 IFSF$=CHR$(13)ANDMW$="[134]"ANDBA$=""THEN3550
5030 IFSF$=CHR$(13)ANDMW$="[134]"ANDBE$=""THEN3590
5040 GOTO4990
5050 PRINT"":PRINTCS$+SN$+" ":PRINT:GOTO4770
5060 SN$=LEFT$(SN$,LEN(SN$)-1):GOTO4650
5070 IFPEEK(50307)=120THEN8000
5075 PRINT"[147] WAHL DES FILENAMENS [146]"
5080 PRINT" BITTE WAEHLEN:"
5090 PRINT" H [146] * HAUSHALTSBELEGE *"
5100 PRINT" F [146] * F I L E N A M E * , WAEHLBAR"
5110 PRINT" <C=><M>[146] MENUE"
5120 GETFW$:IFFW$=CHR$(167)THENRUN
5130 IFFW$="F"THEN5160
5140 IFFW$="H"THENFI$="HAUSHALTSBELEGE":GOTO5210
5150 GOTO5120
5160 PRINT" EINGABE DES FILENAMENS "
5170 PRINT" "
5180 KL=16:N$="................"
5190 GOTO2530
5200 REM **************** A B S P E I C H E R N *****************
5210 PRINT" WAHL DES SPEICHERMEDIUMS [146]"
5220 IFFW$="F"THENPRINT"";SPC(21);" "
5230 IFFW$="H"THENPRINT" HAUSHALTSBELEGE"
5240 PRINT" B [146] BAND "
5250 PRINT" D [146] DISKETTE "
5260 GETSW$:IFSW$=CHR$(167)THENRUN
5270 IFSW$="D"THEN6100
5280 IFSW$="B"THEN6230
5290 GOTO5260
5300 PRINT"[147] ARBEITSCASSETTE IM RECORDER ? [146]"
5310 PRINT" <C=><M>[146] MENUE"
5320 PRINT" <S>[146] SAVE'";FI$;"',";RA:PRINT
5330 GETSP$:IFSP$=CHR$(167)THENRUN
5340 IFSP$=CHR$(83)THEN5360
5350 GOTO5330
5360 SAVEFI$,RA,1:PRINT
5370 PRINT" VERIFIZIEREN ? [146]"
5380 PRINT" V [146] VERIFY, WENN ZURUECKGESPULT!"
5390 PRINT" <C=><M>[146] MENUE"
5400 GETVF$:IFVF$=CHR$(167)THENRUN
5410 IFVF$="V"THEN5430
5420 GOTO5400
5430 IFFW$="F"THENVERIFYFI$,RA
5440 FORI=1TO2000:NEXT:RUN
5450 PRINT"[147] ARBEITSDISKETTE IM LAUFWERK ? [146]"
5460 PRINT" FLOPPY IST EMPFANGSBEREIT "
5470 PRINT" <C=><M>[146] MENUE"
5480 IFFW$="F"THEN5500
5490 PRINT" <S>[146] SAVE'@:HAUSHALTSBELEGE',";FA:GOTO5510
5500 PRINT" <S>[146] SAVE'";FI$;"',";FA
5510 GETSP$:IFSP$=CHR$(167)THENRUN
5520 IFSP$="S"THEN5540
5530 GOTO5510
5540 IFFW$="H"THENSAVE"@:HAUSHALTSBELEGE",FA
5550 IFFW$="F"THENSAVEFI$,FA
5560 GOSUB6300
5600 GETVF$:IFVF$=CHR$(167)THENRUN
5620 GOTO5600
5650 REM ******** E I N G A B E U E B E R P R U E F U N G *********
5660 P1$=MID$(B$,13,1)
5670 P2$=RIGHT$(B$,1)
5680 IFP1$="."ANDP2$="+"THEN6400
5690 IFP1$="."ANDP2$="-"THEN6400
5700 IFP1$<>"."ORP2$<>"+"ORP2$<>"-"THENPRINT"[147]"
5710 PRINT"R I C H T I G E"
5720 PRINT"E I N G A B E I N"
5730 PRINT"B E L E G - N R .: ";BN$;"?"
5740 PRINT"";CHR$(18);" ";LEFT$(B$,8);" ";MID$(B$,9,7);
5750 PRINT" ";CHR$(18);MID$(B$,16,12);" ";RIGHT$(B$,1);" "
5760 IFP1$<>"."ANDP2$<>"+"ANDP2$<>"-"THENGOTO5800
5770 IFP1$<>"."ANDP2$="+"THENGOTO5810
5780 IFP1$<>"."ANDP2$="-"THENGOTO5810
5790 IFP2$<>"+"ANDP2$<>"-"THENGOTO5820
5800 PRINT" ^ ^":GOTO5830
5810 PRINT" ^":GOTO5830
5820 PRINT" ^"
5830 PRINT" A [146] ABLAGE"
5840 PRINT" N [146] NEUEINGABE"
5850 PRINT"<C=><M>[146] MENUE"
5860 GETPF$:IFPF$=CHR$(167)THENRUN
5870 IFPF$="N"THENE$="":GOTO1350
5880 IFPF$="A"THEN6400
5890 GOTO5860
5900 REM **** W A H L D E R G E R A E T E A D R E S S E N ****
5910 PRINT"[147] WAHL DER DRUCKERADRESSE [146]"
5920 PRINT" BITTE WAEHLEN:"
5930 PRINT" 4 [146] DRUCKER"
5940 PRINT" 5 [146] DRUCKER"
5950 PRINT" 6 [146] PLOTTER"
5960 PRINT" <C=><M>[146] MENUE"
5970 GETGA$:IFGA$=CHR$(167)THENRUN
5980 GA=VAL(GA$)
5990 IFGA<>4ANDGA<>5ANDGA<>6THEN5970
6000 IFLEN(GA$)=1THEN6020
6010 GOTO5970
6020 OPENGA,GA:POKE768,61
6030 PRINT#GA:CLOSEGA:POKE768,139
6040 IFST<>-128THEN3650
6045 PRINT""
6050 PRINT"";
6060 PRINTCHR$(18);" GERAETEADRESSE ";"[157]"GA;"[157] "
6070 PRINT"";
6080 PRINTCHR$(18);" IST NICHT EMPFANGSBEREIT "
6090 GOTO5970
6100 PRINT" WAHL DER FLOPPYADRESSE [146]"
6110 PRINT" 8 [146] FLOPPY "
6120 PRINT" 9 [146] FLOPPY "
6130 GETFA$:IFFA$=CHR$(167)THENRUN
6140 FA=VAL(FA$)
6150 IFFA<>8ANDFA<>9THEN6130
6160 IFLEN(FA$)=1THENPOKE768,61
6170 POKE144,0:OPEN1,FA,0:CLOSE1:POKE768,139
6180 IFST<>-128THEN5450
6185 PRINT"[145]";
6190 PRINT"";
6200 PRINTCHR$(18);" FLOPPY ";"[157]"FA"[157] IST NICHT "
6210 PRINT"";
6220 PRINTCHR$(18);" EMPFANGSBEREIT! ":PRINT"[145]";:GOTO6130
6230 IFPEEK(50307)=120THEN8000
6232 PRINT" WAHL DER RECORDERADRESSE [146]"
6240 PRINT" 1 [146] NORMALTAPE"
6250 PRINT" 7 [146] SUPERTAPE"
6260 GETRA$:IFRA$=CHR$(167)THENRUN
6270 RA=VAL(RA$)
6272 IFRA=7ANDPEEK(817)=244THEN6500
6280 IFRA<>1ANDRA<>7THEN6260
6290 IFLEN(RA$)=1THEN5300
6300 OPEN15,FA,15:INPUT#15,MN,M$,MT,MS:CLOSE15
6310 IFMN=0THEN6330
6320 PRINT"[147] FLOPPYFEHLERKANAL [146]"
6330 PRINT"";MN; M$;MT;MS:IFMN=0THENRETURN
6340 PRINT" Z [146] ZURUECK ZUM 'SAVE'"
6350 PRINT" <C=><M>[146] MENUE"
6360 GETFK$:IFFK$=CHR$(167)THENRUN
6370 IFFK$="Z"THEN6170
6380 GOTO6360
6390 REM *********** D A T A A U F B E R E I T U N G ************
6400 IFBN<10THEND$=""+STR$(BN)+"[157][157][157]00"+""+B$
6410 IFBN>9ANDBN<100THEND$=""+STR$(BN)+"[157][157][157]0"+""+B$
6420 IFBN=>100THEND$=STR$(BN)+B$
6425 PRINT""
6430 PRINT"[147][157]"DZ"DATA"D$
6440 IFK=0THENPRINT"10000 DATA"DZ
6450 PRINT"RUN"
6460 POKE631,19:POKE632,13:POKE633,13:POKE634,13:POKE198,4
6470 END
6500 PRINT"":PRINT"";
6502 PRINTCHR$(18);"SUPERTAPE IST "
6510 PRINT"";
6512 PRINTCHR$(18);"NICHT AKTIVIERT !!"
6520 GOTO6260
8000 PRINT"[147]"
8010 PRINT:PRINT:PRINT" [144] DAS [146]INPUT 64[146][144] - BETRIEBSSYSTEM [146][154]"
8020 PRINT:PRINT" BEFINDET SICH IM RECHNER."
8030 PRINT:PRINT:PRINT"ZUR ZEIT KANN VON DIESEM PROGRAMM AUS- "
8040 PRINT"GEHEND NICHT GESPEICHERT WERDEN."
8050 PRINT
8060 PRINT"DIESES PROGRAMM BITTE ERST MIT CTRL S"
8070 PRINT"AUF IHREN EIGENEN DATENTRAEGER "
8080 PRINT"ABSPEICHERN."
8970 POKE214,20:POKE211,2:SYS58640
8980 PRINT"BITTE TASTE DRUECKEN!"
8990 GETX$:IFX$=""THEN8990
9000 RUN
9990 REM ***************** D A T A A B L A G E ******************
10000 DATA 10000
11000 DATA ENDE